git.zerfleddert.de Git - proxmark3-svn/blob - fpga/fpga_hf.v

   1 //-----------------------------------------------------------------------------
   2 // The FPGA is responsible for interfacing between the A/D, the coil drivers,
   3 // and the ARM. In the low-frequency modes it passes the data straight
   4 // through, so that the ARM gets raw A/D samples over the SSP. In the high-
   5 // frequency modes, the FPGA might perform some demodulation first, to
   6 // reduce the amount of data that we must send to the ARM.
   7 //
   8 // I am not really an FPGA/ASIC designer, so I am sure that a lot of this
   9 // could be improved.
  10 //
  11 // Jonathan Westhues, March 2006
  12 // Added ISO14443-A support by Gerhard de Koning Gans, April 2008
  13 //-----------------------------------------------------------------------------
  14
  15 `include "hi_read_tx.v"
  16 `include "hi_read_rx_xcorr.v"
  17 `include "hi_simulate.v"
  18 `include "hi_iso14443a.v"
  19 `include "util.v"
  20
  21 module fpga_hf(
  22         input spck, output miso, input mosi, input ncs,
  23         input pck0, input ck_1356meg, input ck_1356megb,
  24         output pwr_lo, output pwr_hi,
  25         output pwr_oe1, output pwr_oe2, output pwr_oe3, output pwr_oe4,
  26         input [7:0] adc_d, output adc_clk, output adc_noe,
  27         output ssp_frame, output ssp_din, input ssp_dout, output ssp_clk,
  28         input cross_hi, input cross_lo,
  29         output dbg
  30 );
  31
  32 //-----------------------------------------------------------------------------
  33 // The SPI receiver. This sets up the configuration word, which the rest of
  34 // the logic looks at to determine how to connect the A/D and the coil
  35 // drivers (i.e., which section gets it). Also assign some symbolic names
  36 // to the configuration bits, for use below.
  37 //-----------------------------------------------------------------------------
  38
  39 reg [15:0] shift_reg;
  40 reg [7:0] conf_word;
  41
  42 // We switch modes between transmitting to the 13.56 MHz tag and receiving
  43 // from it, which means that we must make sure that we can do so without
  44 // glitching, or else we will glitch the transmitted carrier.
  45 always @(posedge ncs)
  46 begin
  47         case(shift_reg[15:12])
  48                 4'b0001: conf_word <= shift_reg[7:0];           // FPGA_CMD_SET_CONFREG
  49         endcase
  50 end
  51
  52 always @(posedge spck)
  53 begin
  54         if(~ncs)
  55         begin
  56                 shift_reg[15:1] <= shift_reg[14:0];
  57                 shift_reg[0] <= mosi;
  58         end
  59 end
  60
  61 wire [2:0] major_mode;
  62 assign major_mode = conf_word[7:5];
  63
  64 // For the high-frequency transmit configuration: modulation depth, either
  65 // 100% (just quite driving antenna, steady LOW), or shallower (tri-state
  66 // some fraction of the buffers)
  67 wire hi_read_tx_shallow_modulation = conf_word[0];
  68
  69 // For the high-frequency receive correlator: frequency against which to
  70 // correlate.
  71 wire hi_read_rx_xcorr_848 = conf_word[0];
  72 // and whether to drive the coil (reader) or just short it (snooper)
  73 wire hi_read_rx_xcorr_snoop = conf_word[1];
  74
  75 // Divide the expected subcarrier frequency for hi_read_rx_xcorr by 4
  76 wire hi_read_rx_xcorr_quarter = conf_word[2];
  77
  78 // For the high-frequency simulated tag: what kind of modulation to use.
  79 wire [2:0] hi_simulate_mod_type = conf_word[2:0];
  80
  81 //-----------------------------------------------------------------------------
  82 // And then we instantiate the modules corresponding to each of the FPGA's
  83 // major modes, and use muxes to connect the outputs of the active mode to
  84 // the output pins.
  85 //-----------------------------------------------------------------------------
  86
  87 hi_read_tx ht(
  88         pck0, ck_1356meg, ck_1356megb,
  89         ht_pwr_lo, ht_pwr_hi, ht_pwr_oe1, ht_pwr_oe2, ht_pwr_oe3, ht_pwr_oe4,
  90         adc_d, ht_adc_clk,
  91         ht_ssp_frame, ht_ssp_din, ssp_dout, ht_ssp_clk,
  92         cross_hi, cross_lo,
  93         ht_dbg,
  94         hi_read_tx_shallow_modulation
  95 );
  96
  97 hi_read_rx_xcorr hrxc(
  98         pck0, ck_1356meg, ck_1356megb,
  99         hrxc_pwr_lo, hrxc_pwr_hi, hrxc_pwr_oe1, hrxc_pwr_oe2, hrxc_pwr_oe3,     hrxc_pwr_oe4,
 100         adc_d, hrxc_adc_clk,
 101         hrxc_ssp_frame, hrxc_ssp_din, ssp_dout, hrxc_ssp_clk,
 102         cross_hi, cross_lo,
 103         hrxc_dbg,
 104         hi_read_rx_xcorr_848, hi_read_rx_xcorr_snoop, hi_read_rx_xcorr_quarter
 105 );
 106
 107 hi_simulate hs(
 108         pck0, ck_1356meg, ck_1356megb,
 109         hs_pwr_lo, hs_pwr_hi, hs_pwr_oe1, hs_pwr_oe2, hs_pwr_oe3, hs_pwr_oe4,
 110         adc_d, hs_adc_clk,
 111         hs_ssp_frame, hs_ssp_din, ssp_dout, hs_ssp_clk,
 112         cross_hi, cross_lo,
 113         hs_dbg,
 114         hi_simulate_mod_type
 115 );
 116
 117 hi_iso14443a hisn(
 118         pck0, ck_1356meg, ck_1356megb,
 119         hisn_pwr_lo, hisn_pwr_hi, hisn_pwr_oe1, hisn_pwr_oe2, hisn_pwr_oe3,     hisn_pwr_oe4,
 120         adc_d, hisn_adc_clk,
 121         hisn_ssp_frame, hisn_ssp_din, ssp_dout, hisn_ssp_clk,
 122         cross_hi, cross_lo,
 123         hisn_dbg,
 124         hi_simulate_mod_type
 125 );
 126
 127 // Major modes:
 128
 129 //   000 --  HF reader, transmitting to tag; modulation depth selectable
 130 //   001 --  HF reader, receiving from tag, correlating as it goes; frequency selectable
 131 //   010 --  HF simulated tag
 132 //   011 --  HF ISO14443-A
 133 //   111 --  everything off
 134
 135 mux8 mux_ssp_clk                (major_mode, ssp_clk,   ht_ssp_clk,   hrxc_ssp_clk,   hs_ssp_clk,   hisn_ssp_clk,   1'b0, 1'b0, 1'b0, 1'b0);
 136 mux8 mux_ssp_din                (major_mode, ssp_din,   ht_ssp_din,   hrxc_ssp_din,   hs_ssp_din,   hisn_ssp_din,   1'b0, 1'b0, 1'b0, 1'b0);
 137 mux8 mux_ssp_frame              (major_mode, ssp_frame, ht_ssp_frame, hrxc_ssp_frame, hs_ssp_frame, hisn_ssp_frame, 1'b0, 1'b0, 1'b0, 1'b0);
 138 mux8 mux_pwr_oe1                (major_mode, pwr_oe1,   ht_pwr_oe1,   hrxc_pwr_oe1,   hs_pwr_oe1,   hisn_pwr_oe1,   1'b0, 1'b0, 1'b0, 1'b0);
 139 mux8 mux_pwr_oe2                (major_mode, pwr_oe2,   ht_pwr_oe2,   hrxc_pwr_oe2,   hs_pwr_oe2,   hisn_pwr_oe2,   1'b0, 1'b0, 1'b0, 1'b0);
 140 mux8 mux_pwr_oe3                (major_mode, pwr_oe3,   ht_pwr_oe3,   hrxc_pwr_oe3,   hs_pwr_oe3,   hisn_pwr_oe3,   1'b0, 1'b0, 1'b0, 1'b0);
 141 mux8 mux_pwr_oe4                (major_mode, pwr_oe4,   ht_pwr_oe4,   hrxc_pwr_oe4,   hs_pwr_oe4,   hisn_pwr_oe4,   1'b0, 1'b0, 1'b0, 1'b0);
 142 mux8 mux_pwr_lo                 (major_mode, pwr_lo,    ht_pwr_lo,    hrxc_pwr_lo,    hs_pwr_lo,    hisn_pwr_lo,    1'b0, 1'b0, 1'b0, 1'b0);
 143 mux8 mux_pwr_hi                 (major_mode, pwr_hi,    ht_pwr_hi,    hrxc_pwr_hi,    hs_pwr_hi,    hisn_pwr_hi,    1'b0, 1'b0, 1'b0, 1'b0);
 144 mux8 mux_adc_clk                (major_mode, adc_clk,   ht_adc_clk,   hrxc_adc_clk,   hs_adc_clk,   hisn_adc_clk,   1'b0, 1'b0, 1'b0, 1'b0);
 145 mux8 mux_dbg                    (major_mode, dbg,       ht_dbg,       hrxc_dbg,       hs_dbg,       hisn_dbg,       1'b0, 1'b0, 1'b0, 1'b0);
 146
 147 // In all modes, let the ADC's outputs be enabled.
 148 assign adc_noe = 1'b0;
 149
 150 endmodule