git.zerfleddert.de Git - proxmark3-svn/blob - bootrom/ldscript-flash

   1 INCLUDE ../common/ldscript.common
   2
   3 ENTRY(flashstart)
   4 SECTIONS
   5 {
   6     . = 0;
   7
   8     bootphase1 : {
   9         *(.startup)
  10         *(.bootphase1)
  11
  12         /* It seems to be impossible to flush align a section at the
  13            end of a memory segment. Instead, we'll put the version_information
  14            wherever the linker wants it, and then put a pointer to the start
  15            of the version information at the end of the section.
  16            -- Henryk Plötz <henryk@ploetzli.ch> 2009-08-28 */
  17
  18         _version_information_start = .;
  19         *(.version_information);
  20
  21         . = LENGTH(bootphase1) - 0x4; /* Skip ahead to the end */
  22         LONG(_version_information_start)
  23     } >bootphase1
  24
  25     bootphase2 : {
  26         __bootphase2_start__ = .;
  27         *(.startphase2)
  28         *(.text)
  29         *(.glue_7)
  30         *(.glue_7t)
  31         *(.rodata)
  32         *(.data)
  33         . = ALIGN( 32 / 8 );
  34         __bootphase2_end__ = .;
  35     } >ram AT>bootphase2
  36
  37     .bss : {
  38         __bss_start__ = .;
  39         *(.bss)
  40     } >ram
  41
  42     . = ALIGN( 32 / 8 );
  43     __bss_end__ = .;
  44 }