git.zerfleddert.de Git - proxmark3-svn/blob - armsrc/ldscript

   1 /*
   2 -----------------------------------------------------------------------------
   3  This code is licensed to you under the terms of the GNU GPL, version 2 or,
   4  at your option, any later version. See the LICENSE.txt file for the text of
   5  the license.
   6 -----------------------------------------------------------------------------
   7  Linker script for the ARM binary
   8 -----------------------------------------------------------------------------
   9 */
  10 INCLUDE ../common/ldscript.common
  11
  12 PHDRS
  13 {
  14         fpgaimage PT_LOAD FLAGS(4);
  15         text PT_LOAD;
  16         data PT_LOAD;
  17         bss PT_LOAD;
  18 }
  19
  20 ENTRY(Vector)
  21 SECTIONS
  22 {
  23         .fpgaimage : {
  24                 *(fpga_bit.data)
  25         } >fpgaimage :fpgaimage
  26
  27         .start : {
  28                 *(.startos)
  29         } >osimage :text
  30
  31         .text : {
  32                 *(.text)
  33                 *(.text.*)
  34                 *(.eh_frame)
  35                 *(.glue_7)
  36                 *(.glue_7t)
  37         } >osimage :text
  38
  39         .rodata : {
  40                 *(.rodata)
  41                 *(.rodata.*)
  42                 *(.version_information)
  43         } >osimage :text
  44
  45         . = ALIGN(4);
  46
  47         .data : {
  48                 *(.data)
  49                 *(.data.*)
  50                 . = ALIGN(4);
  51         } >ram AT>osimage :data
  52
  53         __data_src_start__ = LOADADDR(.data);
  54         __data_start__ = ADDR(.data);
  55         __data_end__ = __data_start__ + SIZEOF(.data);
  56
  57         .bss : {
  58                 __bss_start__ = .;
  59                 *(.bss)
  60                 *(.bss.*)
  61                 . = ALIGN(4);
  62                 __bss_end__ = .;
  63         } >ram :bss
  64
  65         .commonarea (NOLOAD) : {
  66                 *(.commonarea)
  67         } >commonarea :NONE
  68 }