fpga_compress: interleave (combine) fpga_lf.bit and fpga_hf.bit before compression.
[proxmark3-svn] / armsrc / ldscript
1 /*
2 -----------------------------------------------------------------------------
3 This code is licensed to you under the terms of the GNU GPL, version 2 or,
4 at your option, any later version. See the LICENSE.txt file for the text of
5 the license.
6 -----------------------------------------------------------------------------
7 Linker script for the ARM binary
8 -----------------------------------------------------------------------------
9 */
10 INCLUDE ../common/ldscript.common
11
12 PHDRS
13 {
14 text PT_LOAD FLAGS(5);
15 data PT_LOAD;
16 bss PT_LOAD;
17 }
18
19 ENTRY(Vector)
20 SECTIONS
21 {
22 .start : {
23 *(.startos)
24 } >osimage :text
25
26 .text : {
27 *(.text)
28 *(.text.*)
29 *(.eh_frame)
30 *(.glue_7)
31 *(.glue_7t)
32 } >osimage :text
33
34 .rodata : {
35 *(.rodata)
36 *(.rodata.*)
37 *(fpga_all_bit.data)
38 KEEP(*(.version_information))
39 } >osimage :text
40
41 . = ALIGN(4);
42
43 .data : {
44 *(.data)
45 *(.data.*)
46 *(.ramfunc)
47 . = ALIGN(4);
48 } >ram AT>osimage :data
49
50 __data_src_start__ = LOADADDR(.data);
51 __data_start__ = ADDR(.data);
52 __data_end__ = __data_start__ + SIZEOF(.data);
53 __os_size__ = SIZEOF(.text) + SIZEOF(.data) + SIZEOF(.rodata);
54
55 .bss : {
56 __bss_start__ = .;
57 *(.bss)
58 *(.bss.*)
59 . = ALIGN(4);
60 __bss_end__ = .;
61 } >ram AT>ram :bss
62
63 .commonarea (NOLOAD) : {
64 *(.commonarea)
65 } >commonarea :NONE
66 }
Impressum, Datenschutz